Use Manipulate to view phase portrait with different initial conditions
Define 2D system here

Parameters and system

{(Subscript[x, min]),(Subscript[x, max])}={-5,5};
{(Subscript[y, min]),(Subscript[y, max])}={-5,5};

f[x_,y_]:=y

g[x_,y_]:=-x-1.5*y*(-1+x*x)

Vector field

V={f[x,y],g[x,y]}

Phase Portrait

solution1=NDSolve[{x'[t]==f[x[t],y[t]],
y'[t]==g[x[t],y[t]],{x[0],y[0]}=={1,1}},{x,y},
{t,0,150},MaxSteps->Infinity,StartingStepSize->0.001];

solution=NDSolve[{x'[t]==f[x[t],y[t]],
y'[t]==g[x[t],y[t]],{x[0],y[0]}=={1,1}},{x,y},
{t,0,130},Method->"ExplicitRungeKutta", MaxSteps->Infinity,StartingStepSize->0.001];

phaseplot=ParametricPlot[Evaluate[{x[t],y[t]}/.solution1],{t,0,150},PlotPoints->1000,PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}},AxesLabel->{"X","Y"},PlotStyle->{{Red,Thickness[0.005]}},AspectRatio->1,Frame->True]

vectorfield=VectorPlot[{f[x,y],g[x,y]},{x,(Subscript[x, min]),(Subscript[x, max])},{y,(Subscript[y, min]),(Subscript[y, max])},VectorPoints->20,VectorScale->{.03,Automatic,None},ColorFunction->(Hue[0.66]&),Frame->True,Axes->True,AxesLabel->{"X","Y"},AspectRatio->1];

Show[phaseplot,vectorfield,ImageSize->{600,600}]

sol=ParametricNDSolveValue[{x'[t]==f[x[t],y[t]],y'[t]==g[x[t],y[t]],x[0]==x0,y[0]==y0 },{x,y},{t,0,20},{x0,y0}]

Manipulate[Plot[Evaluate[#[t]&/@sol[x0,y0]],{t,0,20},PlotLegends->{x,y}],{{x0,1},0,2},{{y0,1},0,2}]

Manipulate[ParametricPlot[Evaluate[#[t]&/@sol[x0,y0]],{t,0,T},PlotPoints->1500,PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}},AxesLabel->{"X","Y"},PlotStyle->{{Red,Thickness[0.005]}},AspectRatio->1,Frame->True],{{x0,1},0,2},{{y0,1},0,2},{{T,2},1,100}]